Create a scorecarding spreadsheet

Introduction

In this tutorial, we are looking to create a scorecards dashboard where for each supplier, we pull critical answers to the sustainability practices questionnaire.

We are going to create an Excel spreadsheet that looks like the following:

Supplier name Is it a material supplier? TSP Response Disclosure Platforms/ External Reporting (GRI, SASB, TCFD)
S1 - Tamerin (Demo) Yes COMPLETED Yes
Is it a material supplier?
We have separated our company's suppliers between material suppliers and others. Material suppliers are either a big spend category, or supplier in an industry contributing significantly to GHG Emissions.
TSP Response
If a supplier is material, then we want them to complete the sustainability practices questionnaire. Otherwise, it is optional.
Disclosure Platforms/ External Reporting (GRI, SASB, TCFD)
This column retrieves directly the answer from the supplier to the question "1.5 Does your company report externally on strategy: program elements, key environmental, social and governance issues, goals, challenges, resiliency, and continual improvement efforts in accordance with a reputable reporting standard (e.g. GRI, SASB, TCFD)?"

Tagging suppliers

Whether the supplier is material or not to our company is not an information directly extracted from TSP at this point. We will add it as a tag labelled material to the Track dashboard.

We use the Track dashboard here because material is not an attribute that applies across multiple years and regardless of the process of requesting the supplier to update their response to the questionnaire.

When to use tags on the Engage dashboard?

When we want to indicate a supplier response should be verified, we do that with a tag labelled verify on the Engage dashboard because this is information for the verification team that relates to a specific timely request to a supplier to update their response to the questionnaire.

Download suppliers data

First, we create an empty spreadsheet named scorecarding.xlsx, and setup the column labels strucutre into the first sheet ("Supplier name", "Is it a material supplier?", "TSP Response", "Disclosure Platforms/ External Reporting (GRI, SASB, TCFD)").

We then browse to the Track dashboard, and select the current yearly period. Since the sustainability practices questionnaire is refreshed on July 4th every year (see content governance process), we set the From input field to 2026-07-04 and the To input field to 2026-12-31, then click Update.

Once the dashboard as updated to reflect the current period, we click Download (.xlsx) to download the response status per supplier, and copy/paste the downloaded file into a sheet named "2026 Track Status" into the scorecarding spreadsheet.

We then click Answers & scores (pivatable .csv) and copy/paste the downloaded file into a sheet named "2026 Track Answers & scores" into the scorecarding spreadsheet.

At this point we have all the information required to build our scorecarding spreadsheet.

Spreadsheet formulas

For each column, we enter a specific formula to retrieve information in the sheets containing the downloaded data. Here the formulas in the first row.

Supplier name
Cell Formula
=$'2026 Track Status'.B2
Is it a material supplier?
Cell Formula
=IF(ISNUMBER(SEARCH("material", $'2026 Track Status'.C2)),"Yes", "No")
TSP Response
Cell Formula
=IF(ISNUMBER(SEARCH("material", $'2026 Track Status'.C2)),
   IF(OR($'2026 Track Status'.E2="responded",
         $'2026 Track Status'.E2="verified",
         $'2026 Track Status'.E2="completed"),
     "COMPLETED",
     "NOT ADDRESSED"),
   IF(OR($'2026 Track Status'.E2="responded",
         $'2026 Track Status'.E2="verified",
         $'2026 Track Status'.E2="completed"),
     "COMPLETED",
     "NOT REQUIRED"))
Disclosure Platforms/ External Reporting (GRI, SASB, TCFD)
Cell Formula
=TEXTJOIN(",", 1,
   IFERROR(FILTER($'2026 Track Answers & scores'.$D$2:$D$205,
     ($'2026 Track Answers & scores'.$C$2:$C$205=A2) *
     ($'2026 Track Answers & scores'.$E$2:$E$205="Yes/No") *
     ($'2026 Track Answers & scores'.$G$2:$G$205=1.5)), "-"))

We have 205 rows in the 2026 Track Answers & scores sheet so that's the extend of the data the filter runs on. We filter the 2026 Track Answers & scores dataset for a specific supplier name (in A2), a specific question (1.5), and a specific unit (Yes/No answer). The multiplications are a trick to create an AND boolean logic between our 3 filtering criteria. We use TEXTJOIN to collapse the result of FILTER to a single cell - in case there are issues with the dataset and we find more than one answer for the same supplier to the same question.

Conclusion

We have seen in this tutorial how to download suppliers responses from TSP, and create a scorecarding dashboard based on both answers to the sustainability practices questionnaire, augmented with information specific to our company through tags.

Download final spreadsheet

To learn more, consider reading:

Need additional help?
Contact us